Reorganize project

modules/default.nix

@@ -0,0 +1,117 @@
+{ pkgs, cluster, customize ? {}, lib, config, ... }:
+with lib;
+let
+  cfg = cluster;
+
+  pki = import ./pki.nix { inherit pkgs; ca = cfg.initca; };
+
+  mkCert = host: {
+    ${host.name} = pki.gencert {
+        cn = host.name;
+        ca = cfg.ca;
+        o = cfg.clusterName;
+      };
+    };
+
+  baseDeployment = nodes: attrs:
+    let
+      hosts =
+        builtins.foldl'
+          (a: x: a // { ${x.name} = mkHost x _; }) {} nodes;
+      hosts' = lib.recursiveUpdate hosts attrs;
+      names = builtins.attrNames hosts;
+    in
+      builtins.foldl' (a: x: a // { ${x} = self: hosts'.${x}; }) {} names;
+
+in {
+  k8s = rec {
+    apiserver = host: self: {
+      deployment.targetHost = host.address;
+
+      inherit customize;
+
+      cluster = mkMerge [
+        cfg
+        {
+          hostName = host.name;
+          cert = mkCert host.name;
+          k8s.master.enable = true;
+          k8s.node.enable = true;
+        }
+      ];
+
+      imports = [ host.hw ./modules.nix ];
+    };
+
+    node = host: self: {
+      deployment.targetHost = host.address;
+
+      inherit customize;
+
+      cluster = mkMerge [
+        cfg
+        {
+          hostName = host.name;
+          cert = mkCert host.name;
+          k8s.node.enable = true;
+        }
+      ];
+
+      imports = [ host.hw ./modules.nix ];
+    };
+
+    mkDeployment = master: nodes:
+      let
+        server = { "${master.name}" = apiserver master; };
+      in
+        builtins.foldl' (a: x:
+          a // { "${x.name}" = node x; }) server nodes;
+  };
+
+  fs = rec {
+    mkNode = host: self: {
+      deployment.targetHost = host.address;
+
+      inherit customize;
+
+      cluster = mkMerge [
+        cfg
+        {
+          hostName = host.name;
+          cert = mkCert host.name;
+        }
+      ];
+
+      imports = [ host.hw ./modules.nix ];
+    };
+
+    mkDeployment = nodes:
+      builtins.foldl' (a: x:
+        a // { "${x.name}" = mkNode x; }) {} nodes;
+  } ;
+
+  host = rec {
+    node = host: self: {
+      deployment.targetHost = host.address;
+
+      inherit customize;
+
+      cluster = mkMerge [
+        cfg
+        {
+          hostName = host.name;
+          cert = mkCert host.name;
+        }
+      ];
+
+      imports = [ host.hw ./modules.nix ];
+    };
+
+    mkDeployment = masterNode: workerNodes:
+      let
+        master = { "${master.name}" =  apiserver masterNode; };
+      in
+        builtins.foldl' (a: x:
+          a // { "${x.name}" = mkWorker x; }) master workerNodes;
+  };
+}

modules/fs.nix

@@ -0,0 +1,65 @@
+{ pkgs, lib, config, ... }:
+with lib;
+let
+  cfg = config.cluster.fs;
+
+  cert = cfg.cert;
+
+  pki = import ./pki.nix { inherit pkgs; ca = cfg.initca; };
+
+  common = {
+    boot.kernelModules = [
+      "dm_snapshot"
+      "dm_mirror"
+      "dm_thin_pool"
+    ];
+
+    networking = {
+      firewall.allowedTCPPortRanges = [ { from = 5000; to = 50000; } ];
+      firewall.allowedTCPPorts = [ 111 2049 ];
+      firewall.allowedUDPPorts = [ 111 2049 24007 24008 ];
+    };
+
+    environment.systemPackages = [ pkgs.lvm2 ];
+  };
+
+  glusterfs = {
+    services.glusterfs = {
+      enable = true;
+      tlsSettings = {
+        caCert = pki.ca.cert;
+        tlsKeyPath = cert.key;
+        tlsPem = cert.cert;
+      };
+    };
+  };
+
+  nfs = {
+    services.nfs.server = {
+      enable = true;
+      exports = cfg.nfs.exports;
+    };
+  };
+in {
+  options.cluster.fs = {
+    enable = mkEnableOption "Enable nfs fileserver";
+    nfs = {
+      enable = mkEnableOption "Enable nfs fileserver";
+      exports = mkOption {
+        type = types.str;
+        default = "";
+      };
+    };
+    glusterfs.enable = mkEnableOption "Enable glusterfs fileserver";
+  };
+
+  config = mkIf cfg.enable (
+    mkMerge [
+      common
+      (mkIf cfg.nfs.enable nfs)
+      (mkIf cfg.glusterfs.enable glusterfs)
+    ]
+  );
+
+  imports = [ ./os.nix ];
+}

modules/initca.nix

@@ -0,0 +1,35 @@
+{ pkgs ? import <nixpkgs> {}, ca ? "", name ? "ca", ...}:
+with pkgs;
+let
+  ca' =
+    let
+      ca_csr = pkgs.writeText "${name}-csr.json" (builtins.toJSON {
+          key = {
+              algo = "rsa";
+              size = 2048;
+          };
+          names = [
+            {
+              CN = "${name}";
+              O = "NixOS";
+              OU = "${name}.pki.caSpec";
+              L = "generated";
+            }
+          ];
+        });
+    in
+      pkgs.runCommand "initca" {
+        buildInputs = [ pkgs.cfssl ];
+      } '' cfssl genkey -initca ${ca_csr} | cfssljson -bare ca; \
+           mkdir -p $out; cp *.pem $out'';
+   initca = if ca != "" then ca else ca';
+in
+  # make ca derivation sha depend on initca cfssl output
+  pkgs.stdenv.mkDerivation {
+    inherit name;
+    src = initca;
+    buildCommand = ''
+      mkdir -p $out;
+      cp -r $src/* $out
+    '';
+  }

modules/k8s.nix

@@ -0,0 +1,283 @@
+{ pkgs, lib, config, ...}:
+with lib;
+let
+  cfg = config.cluster;
+
+  pki = import ./pki.nix { inherit pkgs; ca = cfg.initca; };
+
+  masterAddress = cfg.k8s.master.address;
+
+  apiserverAddress = "https://${masterAddress}:4443";
+
+  cfssl-apitoken =
+    let
+      apitoken = pkgs.stdenv.mkDerivation {
+        name = "apitoken";
+        buildCommand = ''
+          head -c ${toString (32 / 2)} /dev/urandom | \
+          od -An -t x | tr -d ' ' > $out
+          chmod 400 $out
+        '';
+      };
+    in
+    # make ca derivation sha depend on initca cfssl output
+    pkgs.stdenv.mkDerivation {
+      name = "cfssl-apitoken";
+      src = apitoken;
+      buildCommand = ''
+        cp $src $out
+      '';
+    };
+
+  kube-system-bootstrap =
+    let
+      workerNodes = pkgs.writeText "kube-worker-nodes" (
+        builtins.foldl' (a: x:
+          a + "  - ${x.address}\n") "" cfg.k8s.nodes);
+      grafanaLdap = pkgs.writeText "grafana-ldap.toml"
+          cfg.k8s.bootstrap.grafana_ldap_toml;
+    in
+    pkgs.stdenv.mkDerivation {
+      name = "kube-system-bootstrap";
+      src = ../bootstrap;
+      buildCommand = ''
+        share=$out/share/kube-system-bootstrap
+        mkdir -p $out/bin
+        mkdir -p $share/bin
+        mkdir -p $share/config
+        mkdir -p $share/charts
+
+        export bash="${pkgs.bash}"
+        export apiserver="${cfg.k8s.master.name}"
+        export apiserverAddress="${cfg.k8s.master.address}"
+        export initca="${pki.initca}"
+        export cluster="${cfg.clusterName}"
+        export fileserver="${cfg.k8s.fileserver}"
+        export acme_email="${cfg.k8s.bootstrap.acme_email}"
+        export grafana_smtp_user="$(echo -n ${cfg.k8s.bootstrap.grafana_smtp_user} | base64 -w0)"
+        export grafana_smtp_password="$(echo -n ${cfg.k8s.bootstrap.grafana_smtp_password} | base64 -w0)"
+        export grafana_ldap_toml="$(cat ${grafanaLdap} | base64 -w0)"
+        export workers="$(cat ${workerNodes})"
+
+        substituteAll $src/bin/initial-kube-system-bootstrap $share/bin/initial-kube-system-bootstrap
+        chmod 755 $share/bin/initial-kube-system-bootstrap
+
+        substituteAll $src/copy-kube-system-bootstrap $out/bin/copy-kube-system-bootstrap
+        chmod 755 $out/bin/copy-kube-system-bootstrap
+
+        cd $src/config
+        for i in *; do
+          substituteAll $i $share/config/$i
+        done
+
+        cd $src/charts
+        for i in *; do
+          substituteAll $i $share/charts/$i
+        done
+
+        cp $src/bin/* $share/bin
+      '';
+    };
+
+  install-apitoken = ''
+      #!${pkgs.bash}/bin/bash
+      set -e
+      if [ -d /var/lib/cfssl ]; then
+        cp ${cfssl-apitoken} /var/lib/cfssl/apitoken.secret
+        chown cfssl /var/lib/cfssl/apitoken.secret
+        chmod 640 /var/lib/cfssl/apitoken.secret
+      else
+        mkdir -p /var/lib/kubernetes/secrets
+        cp ${cfssl-apitoken} /var/lib/kubernetes/secrets/apitoken.secret
+        chown root /var/lib/kubernetes/secrets/apitoken.secret
+        chmod 600 /var/lib/kubernetes/secrets/apitoken.secret
+      fi
+    '';
+
+  kubeMaster = {
+    services.cfssl.ca = pki.ca.cert;
+    services.cfssl.caKey = pki.ca.key;
+    services.kubernetes = {
+      roles = [ "master" ];
+      inherit apiserverAddress;
+      masterAddress = cfg.k8s.master.name;
+      clusterCidr = cfg.k8s.cidr;
+      pki.genCfsslCACert = false;
+      pki.genCfsslAPIToken = false;
+      pki.caCertPathPrefix = "${pki.initca}/ca";
+
+      kubelet = {
+        clusterDomain = "${cfg.clusterName}.local";
+      };
+
+      apiserver = {
+        advertiseAddress = masterAddress;
+        authorizationMode = [ "Node" "RBAC" ];
+        allowPrivileged = true;
+        securePort = 4443;
+        insecurePort = 8080;
+        extraOpts = "--requestheader-client-ca-file ${pki.ca.cert}";
+        extraSANs = cfg.k8s.master.extraSANs;
+        # verbosity = 4;
+      };
+
+      controllerManager = {
+        bindAddress = masterAddress;
+        extraOpts = "--authorization-always-allow-paths=/healthz,/metrics";
+      };
+
+      scheduler.address = masterAddress;
+
+      addonManager.enable = true;
+      addons = {
+        dns = {
+          enable = true;
+          clusterDomain = "${cfg.clusterName}.local";
+          reconcileMode = "EnsureExists";
+        };
+      };
+    };
+
+    services.etcd = {
+      listenClientUrls = [ "https://${masterAddress}:2379" ];
+    };
+
+    networking.firewall = {
+      allowedTCPPorts = [ 53 5000 8080 4443 4001 2379 2380 10250 10251 10252 ];
+      allowedUDPPorts = [ 53 4053 ];
+    };
+
+    environment.systemPackages = [
+      pkgs.kubernetes-helm
+      pkgs.kubectl
+      kube-system-bootstrap
+    ];
+
+    systemd.services.kube-certmgr-apitoken-bootstrap = {
+      description = "Kubernetes certmgr bootstrapper";
+      wantedBy = [ "cfssl.service" ];
+      before = [ "cfssl.target" ];
+      script = install-apitoken;
+      serviceConfig = {
+        RestartSec = "10s";
+        Restart = "on-failure";
+      };
+    };
+    systemd.services.cfssl-restart  = {
+      enable = true;
+      startAt  = "00/6:00";
+      description = "Restrart cfssl which regularly locks up";
+      script = "systemctl restart cfssl.service";
+    };
+  };
+
+  kubeNode = {
+    services.kubernetes = rec {
+      roles = [ "node" ];
+      inherit apiserverAddress;
+      masterAddress = cfg.k8s.master.name;
+      clusterCidr = cfg.k8s.cidr;
+      kubelet.clusterDomain = "${cfg.clusterName}.local";
+    };
+
+    networking = {
+      firewall = {
+        enable = true;
+        allowedTCPPorts = [ 4194 10250 ];
+        allowedUDPPorts = [ 53 ];
+        extraCommands = ''iptables -m comment --comment "pod external access" -t nat -A POSTROUTING ! -d 10.10.0.0/16 -m addrtype ! --dst-type LOCAL -j MASQUERADE'';
+      };
+    };
+    virtualisation.docker.extraOptions = "--insecure-registry 10.0.0.0/8";
+    virtualisation.docker.autoPrune.enable = true;
+    systemd.services.kube-certmgr-apitoken-bootstrap = {
+      description = "Kubernetes certmgr bootstrapper";
+      wantedBy = [ "certmgr.service" ];
+      before = [ "certmgr.service" ];
+      script = install-apitoken;
+      serviceConfig = {
+        RestartSec = "10s";
+        Restart = "on-failure";
+      };
+    };
+  };
+
+in {
+  options.cluster.k8s = {
+    enable = mkEnableOption "Enable kubernetes";
+    nodes = mkOption {
+      type = types.listOf types.attrs;
+      default = [];
+    };
+
+    fileserver = mkOption {
+      type = types.str;
+      default = null;
+    };
+
+    cidr = mkOption {
+      type = types.str;
+      default = "10.0.0.0/16";
+    };
+
+    master = {
+      enable = mkEnableOption "Enable kubernetes master node";
+
+      address = mkOption {
+        type = types.str;
+        default = null;
+      };
+
+      name = mkOption {
+        type = types.str;
+        default = null;
+      };
+
+      extraSANs = mkOption {
+        type = types.listOf types.str;
+        default = [];
+      };
+
+      hw = mkOption {
+        type = types.path;
+        default = null;
+      };
+    };
+
+    node = {
+      enable = mkEnableOption "Enable kubernetes";
+    };
+
+    bootstrap = {
+      acme_email = mkOption {
+        type = types.str;
+        default = "";
+      };
+
+      grafana_smtp_user = mkOption {
+        type = types.str;
+        default = "";
+      };
+
+      grafana_smtp_password = mkOption {
+        type = types.str;
+        default = "";
+      };
+
+      grafana_ldap_toml = mkOption {
+        type = types.str;
+        default = "";
+      };
+    };
+  };
+
+  config = mkIf cfg.k8s.enable (
+    mkMerge [
+      (mkIf cfg.k8s.master.enable kubeMaster)
+      (mkIf cfg.k8s.node.enable kubeNode)
+    ]
+  );
+
+  imports = [ ./os.nix ];
+}
+

modules/modules.nix

@@ -0,0 +1,7 @@
+{
+  imports = [
+    ./os.nix
+    ./fs.nix
+    ./k8s.nix
+  ];
+}

modules/os.nix

@@ -0,0 +1,84 @@
+{ pkgs, lib, config, ... }:
+with lib;
+let
+  cfg = config.cluster;
+
+  pki = import ./pki.nix { inherit pkgs; ca = cfg.initca; };
+in
+{
+  options.cluster = {
+    initca = mkOption {
+      type = types.path;
+    };
+
+    hostName = mkOption {
+      type = types.str;
+      default = null;
+    };
+
+    # domain = mkOption {
+    #   type = types.str;
+    #   default = "local";
+    # };
+
+    # searchDomains = mkOption {
+    #   type = types.listOf types.str;
+    #   default = [ cfg.domain ];
+    # };
+
+    cert = mkOption {
+      type = types.attrs;
+      default = null;
+    };
+
+    clusterName = mkOption {
+      type = types.str;
+      default = null;
+    };
+
+    extraHosts = mkOption {
+      type = types.str;
+    };
+
+    adminAuthorizedKeys = mkOption {
+      type = types.listOf types.str;
+      default = [];
+    };
+  };
+
+  config = {
+    users.extraUsers.admin.openssh.authorizedKeys.keys =
+      cfg.adminAuthorizedKeys;
+
+    users.extraUsers.root.openssh.authorizedKeys.keys =
+      cfg.adminAuthorizedKeys;
+
+    networking = {
+      hostName = cfg.hostName;
+      # domain = cfg.domain;
+      # search = cfg.searchDomains;
+      extraHosts = cfg.extraHosts;
+    };
+
+   security.pki.certificateFiles = [ pki.ca.cert ];
+    boot.kernel.sysctl = {
+      "kernel.mm.transparent_hugepage.enabled" = "never";
+      "net.core.somaxconn" = "512";
+    };
+
+    networking = {
+      firewall.allowedTCPPortRanges = [ { from = 5000; to = 50000; } ];
+      firewall.allowedTCPPorts = [ 80 443 111 ];
+      firewall.allowedUDPPorts = [ 111 24007 24008 ];
+    };
+
+    environment.systemPackages = with pkgs; [
+      nfs-utils
+    ];
+  };
+
+  imports = [
+    ../nixos/configuration.nix
+  ];
+
+}

modules/pki.nix

@@ -0,0 +1,82 @@
+{ pkgs, ca ? "" }:
+let
+  initca = import ./initca.nix { inherit pkgs ca; };
+
+  ca' = {
+    key = "${initca}/ca-key.pem";
+    cert = "${initca}/ca.pem";
+  };
+
+  ca-config = pkgs.writeText "ca-config.json" ''
+  {
+      "signing": {
+          "default": {
+              "expiry": "8760h"
+          },
+          "profiles": {
+              "default": {
+                  "usages": [
+                      "signing",
+                      "key encipherment",
+                      "server auth",
+                      "client auth"
+                  ],
+                  "expiry": "8760h"
+              }
+          }
+      }
+  }
+  '';
+
+  gencsr = args:
+    let
+      csr = {
+        CN = "${args.cn}";
+        key = {
+          algo = "rsa";
+          size = 2048;
+        };
+        names = [
+          {
+            CN = "${args.cn}";
+            O = "${args.o}";
+            OU = "${args.cn}.${args.o}.pki.caSpec";
+            L = "generated";
+          }
+        ];
+        hosts = [ "${args.hosts}" ];
+      };
+    in
+      pkgs.writeText "${args.cn}-csr.json" (builtins.toJSON csr);
+in
+# Example usage:
+#
+# gencert { cn = "test"; ca = ca; o = "test; };
+#
+rec {
+  inherit initca;
+  ca = ca';
+  gencert = attrs:
+    let
+      conf = {
+        cn = attrs.cn;
+        ca = attrs.ca;
+        csr = gencsr { cn = attrs.cn; o = attrs.o; hosts = ""; };
+      };
+      cfssl = conf:
+        ''
+          cfssl gencert -ca ${ca.cert} -ca-key ${ca.key} \
+          -config=${ca-config} -profile=default ${conf.csr} | \
+          cfssljson -bare cert; \
+          mkdir -p $out; cp *.pem $out
+        '';
+      crt =
+        pkgs.runCommand "${attrs.cn}" {
+          buildInputs = [ pkgs.cfssl ];
+        } (cfssl conf);
+    in
+    {
+      key = "${crt}/cert-key.pem";
+      cert = "${crt}/cert.pem";
+    };
+}